buildscript {
    dependencies {
        classpath fileTree(dir: 'plugins', include: '*.jar', exclude: '*-sources.jar')
    }
}

repositories {
    jcenter()
}

dependencies {
    plugin 'org.asciidoctor:asciidoctor-gradle-plugin:1.5.0'
}


apply plugin: 'org.asciidoctor.gradle.asciidoctor'

task copySwagger(type: Copy) {
    description('Copies swagger generated documents to a temp dir')
    from file('../swagger/build/asciidoc')
    into 'build/asciidoc-src'
}
copySwagger.dependsOn(':swagger:swaggerToAsciidoc')

task copySources(type: Copy) {
    description('Copies swagger generated documents to a temp dir')
    from file('src/asciidoc')
    into 'build/asciidoc-src'
}

asciidoctor {
    backends = ['html', 'docbook']
    sourceDir = file('build/asciidoc-src')
    sourceDocumentNames = fileTree('build/asciidoc-src') {
        include 'hws.asc'
        include 'hws-internal.asc'
    }
}
asciidoctor.dependsOn 'copySwagger', 'copySources'

task prepXml(type: Copy) {
    description 'moves our DocBook XML (from asciidoctor) into place'
    from 'build/asciidoc/hws.xml'
    into 'xml'
    dependsOn 'asciidoctor'
}

ant.importBuild('build.xml')

publicsite.dependsOn prepXml
pdf.dependsOn prepXml

task publicsiteTar(type: Tar) {
    dependsOn publicsite
    baseName 'helix-web-services-doc'
    version null
    from file('publicsite-generated')
    compression Compression.GZIP
}

task docJar(type: Jar) {
    classifier = 'doc'
    baseName = 'helix-web-services'
    from 'publicsite-generated'
    into 'publicsite/api/doc'
}
// The ant task doesn't really work in general directories, this dependency
// will probably not generically work.
//jar.dependsOn 'publicsite'

clean {
    delete "generated-output"
    delete "publicsite-generated"
    delete "xml"
    delete "helix-web-services-doc.tgz"
}