plugins {
    id 'java-library'
    id 'jacoco'
    id 'org.jenkins-ci.jpi' version '0.50.0'
    id 'com.github.spotbugs' version '5.0.6'
}

group = 'org.jenkins-ci.plugins'
version = '1.14.5-SNAPSHOT'
description = 'Perforce Client plugin for the Jenkins SCM provider.'
java.sourceCompatibility = JavaVersion.VERSION_11

ext{
    scmConnection = 'scm:git:https://github.com/jenkinsci/${project.artifactId}-plugin.git'
    scmDeveloperConnection = 'scm:git:git@github.com:jenkinsci/${project.artifactId}-plugin.git'
    scmUrl= 'https://github.com/jenkinsci/${project.artifactId}-plugin'
    scmTag = 'p4-1.14.4'
}

jenkinsPlugin{
    jenkinsVersion = '2.361.4'
    url = 'https://plugins.jenkins.io/p4/'

    developers {
        developer {
            id 'p4paul'
            name 'Paul Allen'
            email 'pallen@perforce.com'
        }
    }
}

test {
    finalizedBy jacocoTestReport
}
jacocoTestReport {
    dependsOn test
    reports {
        xml.required = false
        csv.required = false
        html.outputLocation = layout.buildDirectory.dir('jacocoHtml')
    }
}

spotbugs {
    ignoreFailures = true
}

repositories {
    mavenCentral()
    maven { url "https://repo.jenkins-ci.org/public/" }
    maven { url "https://artifactory.bnr.perforce.com:8443/artifactory/snapshots" }
    maven { url "https://repo.maven.apache.org/maven2/" }
}

configurations.configureEach {
    resolutionStrategy.force 'org.jenkins-ci.main:jenkins-test-harness:1903.vf505ecb_63589'
}

//https://github.com/gradle/gradle/issues/13656
class ClearDependencies implements ComponentMetadataRule {
    void execute(ComponentMetadataContext context) {
        context.details.allVariants { withDependencies { clear() } }
    }
}
dependencies {
    components {
        withModule('org.dom4j:dom4j', ClearDependencies)
    }
    implementation platform('org.jenkins-ci.plugins:plugin:4.52')
    compileOnly 'org.jenkins-ci.main:jenkins-core:2.361.4'
    implementation 'com.perforce:p4java:2022.1.2423241'
    implementation 'com.jcraft:jzlib:1.1.3-kohsuke-1'
    implementation 'org.apache.commons:commons-lang3:3.12.0'
    implementation 'org.apache.commons:commons-exec:1.3'
    implementation 'com.google.code.gson:gson:2.9.0'
    implementation 'com.mashape.unirest:unirest-java:1.4.9'
    implementation 'org.apache.httpcomponents:httpclient:4.5.13'
    implementation 'org.apache.httpcomponents:httpmime:4.5.13'
    implementation 'org.jenkins-ci.plugins:credentials:1143.vb_e8b_b_ceee347'
    implementation 'org.jenkins-ci.plugins:scm-api:621.vda_a_b_055e58f7'
    implementation 'org.jenkins-ci.plugins:matrix-project:772.v494f19991984'
    implementation 'org.jenkins-ci.plugins:structs:324.va_f5d6774f3a_d'
    implementation 'org.jenkins-ci.plugins:command-launcher:90.v669d7ccb_7c31'

    /** Workflow **/
    implementation 'org.jenkins-ci.plugins.workflow:workflow-step-api:639.v6eca_cd8c04a_a_'
    implementation 'org.jenkins-ci.plugins.workflow:workflow-multibranch:716.vc692a_e52371b_'
    implementation 'org.jenkins-ci.plugins:script-security:1229.v4880b_b_e905a_6'
    implementation 'org.jenkins-ci.plugins.workflow:workflow-scm-step:400.v6b_89a_1317c9a_'
    implementation 'org.jenkins-ci.plugins.workflow:workflow-api:1200.v8005c684b_a_c6'

    implementation 'org.jenkins-ci.plugins:multiple-scms:0.6'
    implementation 'org.jenkins-ci.plugins:mailer:435.v79ef3972b_5c7'

    /** Overridden **/
    implementation 'org.jenkinsci.plugins:pipeline-model-api:2.2118.v31fd5b_9944b_5'
    implementation 'org.jenkins-ci.plugins.workflow:workflow-job:1207.ve6191ff089f8'
    implementation 'org.jenkins-ci.plugins.workflow:workflow-cps:3536.vb_8a_6628079d5'
    implementation 'org.apache.commons:commons-text:1.10.0'
    implementation 'com.fasterxml.woodstox:woodstox-core:6.4.0'
    implementation 'commons-io:commons-io:2.11.0'
    implementation 'commons-codec:commons-codec:1.15'
    implementation 'org.jenkins-ci.plugins:display-url-api:2.3.6'
    implementation 'org.json:json:20220320'
    implementation 'org.jenkins-ci.plugins:jackson2-api:2.13.4.20221013-295.v8e29ea_354141'
    implementation 'org.jenkins-ci.plugins.workflow:workflow-support:839.v35e2736cfd5c'
    implementation 'io.jenkins.plugins:jakarta-mail-api:2.0.1-2'
    implementation 'org.yaml:snakeyaml:2.0'
    /** Overridden **/

    testImplementation 'org.jenkins-ci.plugins:matrix-auth:3.1.5'
    testImplementation 'org.jenkins-ci.plugins.workflow:workflow-durable-task-step:1217.v38306d8fa_b_5c'
    testImplementation 'org.jenkins-ci.plugins.workflow:workflow-basic-steps:994.vd57e3ca_46d24'
    testImplementation 'org.jenkins-ci:test-annotations:1.4'
    testImplementation 'org.junit.jupiter:junit-jupiter:5.9.0'
    testImplementation 'org.junit.vintage:junit-vintage-engine:5.9.0'
    testImplementation 'org.jenkins-ci.plugins:pipeline-stage-step:296.v5f6908f017a_5'
    testImplementation 'org.jenkinsci.plugins:pipeline-model-definition:2.2118.v31fd5b_9944b_5'
    testImplementation 'org.mockito:mockito-core:4.6.1'
}