configure.ac #6

dnl Process this file with autoconf to produce a configure script
# $Id: configure.ac,v 0.4 2003/12/15 15:03:33 bcx Exp bcx $
# 
# Acceptable arguments to configure are:
# 	The usual CC= etc.
#	--with-berkeleydb41=/path define a base for Berkeley DB 4.2
#	--with-installdir=/path define where to install the slowmilter
#	--with-uniquename=dbname define if you compiled libdb this way
# 	--with-wall forces CC=gcc -Wall
#	--with-purify forces CC="purify $CC"
# 
# @start1

AC_INIT(slowmilt, [1.0.5], [slowmilt-bugs@bcx.com])

AC_COPYRIGHT([Copyright (c) 2003 Bryan Costales and Purforce, Inc.])
AC_REVISION([1.0.5])

AC_ARG_WITH([installdir],
	AC_HELP_STRING([--with-installdir=/path], [(default =/etc/mail/milter/slow)]),
	SLOWMILT_BASE=$withval, SLOWMILT_BASE=/etc/mail/milter/slow)
AC_SUBST(SLOWMILT_DIR, $SLOWMILT_BASE)
AC_SUBST(SLOWMILT_EDIT, slowedit)

AC_PREREQ(2.52)
AC_CONFIG_SRCDIR(./milter.c)
AC_CONFIG_AUX_DIR(build)
AC_CANONICAL_SYSTEM
AC_PROG_MAKE_SET
AM_INIT_AUTOMAKE(slowmilt, [1.0.5])

AC_PROG_CC(gcc cc)
AC_CONFIG_HEADERS(config.h)

AC_ARG_WITH([uniquename],
	AC_HELP_STRING([--with-uniquename=dbname], [(no default)]),
	BDB_SUFFIX=$withval,
	BDB_SUFFIX="")
AC_ARG_WITH([berkeleydb4],
	AC_HELP_STRING([--with-berkeleydb4=/path], [(default =/usr/local/BerkeleyDB.4.2)]),
	BDB_BASE=$withval,
	BDB_BASE=/usr/local/BerkeleyDB.4.2)
AC_EGREP_HEADER([struct __mutex_t], $BDB_BASE/include/db.h,
	CPPFLAGS="$CPPFLAGS -I$BDB_BASE/include",
	AC_MSG_ERROR([Require __mutex_t in db.h. (Probably not 4.2) Configure aborted.]))
AC_CHECK_HEADERS(db.h)
SAVE_LDFLAGS="$LDFLAGS"
LDFLAGS="$LDFLAGS -L$BDB_BASE/lib"
AC_CHECK_LIB(        db-4.2, db_create$BDB_SUFFIX,BDB_LIB=$BDB_BASE/lib/libdb-4.2.a,
	AC_CHECK_LIB( db4.2, db_create$BDB_SUFFIX,BDB_LIB=$BDB_BASE/lib/libdb4.2.a,
	AC_CHECK_LIB(  db41, db_create$BDB_SUFFIX,BDB_LIB=$BDB_BASE/lib/libdb41.a,
	AC_CHECK_LIB(    db, db_create$BDB_SUFFIX,BDB_LIB=$BDB_BASE/lib/libdb.a,
	AC_MSG_ERROR([No libdb${BDB_SUFFIX}.a: A Berkeley DB 4.2 library required])))))
LDFLAGS="$SAVE_LDFLAGS"
LIBS="$LIBS $BDB_LIB"

AC_HEADER_STDC
AC_HEADER_TIME
AC_CHECK_HEADERS(sysexits.h)
AC_CHECK_HEADERS(stdio.h)
AC_CHECK_HEADERS(syslog.h)
AC_CHECK_HEADERS(time.h)
AC_CHECK_HEADERS(netdb.h)
AC_CHECK_HEADERS(errno.h)
AC_CHECK_HEADERS(pthread.h)
AC_CHECK_HEADERS(ctype.h)
AC_CHECK_HEADERS(fcntl.h)
AC_CHECK_HEADERS(sys/param.h)
AC_CHECK_HEADERS(sys/socket.h)
AC_CHECK_HEADERS(netinet/in.h)
AC_CHECK_HEADERS(arpa/inet.h)
AC_CHECK_HEADERS(arpa/nameser.h)

AC_C_BIGENDIAN
AC_STRUCT_TM
AC_C_CONST
AC_TYPE_SIZE_T
AC_CHECK_SIZEOF(long)
AC_CHECK_SIZEOF(int)
AC_CHECK_SIZEOF(short)
AC_CHECK_SIZEOF(char)
AC_CHECK_SIZEOF(size_t)
AC_CHECK_SIZEOF(long long)
AC_CHECK_SIZEOF(unsigned long long)
AC_CHECK_SIZEOF(void *)

AC_FUNC_MALLOC
AC_FUNC_REALLOC

AC_CHECK_LIB(malloc, bsdmalloc)
AC_CHECK_LIB(nsl, gethostbyname)
AC_CHECK_LIB(socket, connect)
AC_CHECK_LIB(resolv, res_query)

AC_CHECK_FUNCS(basename)
AC_CHECK_FUNCS(syslog)
AC_CHECK_FUNCS(cuserid)
AC_CHECK_FUNCS(memset bzero, break)
AC_CHECK_FUNCS(memcpy bcopy, break)
AC_CHECK_FUNCS(strerror)
AC_CHECK_FUNCS(strchr)
AC_CHECK_FUNCS(strrchr)
AC_CHECK_FUNCS(strdup)
AC_CHECK_FUNCS(strpbrk)
AC_CHECK_FUNCS(getipnodebyaddr)
AC_CHECK_FUNCS(getipnodebyname)
AC_CHECK_FUNCS(gethostname)
AC_CHECK_FUNCS(gethostbyname)
AC_CHECK_FUNCS(gethostbyaddr)
AC_CHECK_FUNCS(inet_ntoa)
AC_CHECK_FUNCS(strcasecmp)
AC_CHECK_FUNCS(strncasecmp)
AC_CHECK_FUNCS(inet_pton inet_aton)

AC_CHECK_HEADERS(regex.h)
AC_CHECK_FUNCS(regcomp)
AC_CHECK_FUNCS(regexec)
AC_CHECK_FUNCS(regerror)


AC_PROG_LN_S
AC_PROG_RANLIB
AC_SUBST(ac_aux_dir)

AC_ARG_WITH([wall],
	AC_HELP_STRING([--with-wall], [(no default)]),
	CC="gcc -Wall",)
dnl ALWAYS_DEFINES="-D_REENTRANT"
SAVE_LIBS="$LIBS"  
SAVE_CFLAGS="$CFLAGS"
SAVE_CC="$CC"
ACX_PTHREAD()
LIBS="$PTHREAD_LIBS $SAVE_LIBS"
CFLAGS="$SAVE_CFLAGS $PTHREAD_CFLAGS"
CC="$PTHREAD_CC"

AC_ARG_WITH([purify],
	AC_HELP_STRING([--with-purify], [(no default)]),
	CC="purify $CC",)

AC_OUTPUT([Makefile],
[test -z "$CONFIG_HEADERS" || echo timestamp > stamp-h.in])
# @end1