build.gradle #2

// dummy version
rootProject.version = "2013.1.CONFIG"

def headChangeProc = 
    "bash ${project.file('gradle/headChange.sh')} ${project.file('build.gradle')}".execute();

headChangeProc.waitFor();
def releaseVersion = headChangeProc.in.text.trim();
rootProject.version = releaseVersion
logger.warn("version:${rootProject.version}");

subprojects {
    apply plugin: 'eclipse'
    apply plugin: 'java'
    apply plugin: 'maven'

    // perforce internal builds have a slightly different set of dependencies than the open source builds
    // run with -Drelease=true to use the internal repo

    if (Boolean.getBoolean('release')) {
       apply from: rootProject.file('gradle/dev-repositories.gradle');
    } else {
       println "development build"
       apply from: rootProject.file('gradle/open-repositories.gradle');
       rootProject.version = releaseVersion + "-dev"
    }
        
    group = "com.perforce.search"

    dependencies {
    	testCompile "org.testng:testng:6.1.1"
    }

    configurations.all {
        resolutionStrategy.cacheChangingModulesFor 0, 'seconds'
        resolutionStrategy.cacheDynamicVersionsFor 0, 'seconds'
    }
	
	// Works around an issue in gradle M6 (GRADLE-1984), which should be resolved in M7.
	eclipse.classpath.file.beforeMerged { classpath -> classpath.entries.clear() }
}

task wrapper(type:Wrapper) {
    gradleVersion='1.10'
    archiveBase = Wrapper.PathBase.PROJECT
    archivePath = './util/gradle-dists'
    distributionBase = Wrapper.PathBase.PROJECT
    distributionPath = './util/gradle-dists'
    distributionUrl = '../../util/gradle-1.10-bin.zip'
}

def projects = [project(':webapp')]
task javadoc(type: Javadoc) { 
     source projects.collect { project -> project.sourceSets.main.allJava } 
     classpath = 
        files( projects.collect { p -> p.sourceSets.main.compileClasspath } ) 
     destinationDir = file('build/javadoc') 
}