<?xml version='1.0'?>
<xsl:stylesheet xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
xmlns:d="http://docbook.org/ns/docbook"
xmlns:fo="http://www.w3.org/1999/XSL/Format"
xmlns:sverb="http://nwalsh.com/xslt/ext/com.nwalsh.saxon.Verbatim"
xmlns:xverb="com.nwalsh.xalan.Verbatim"
xmlns:lxslt="http://xml.apache.org/xslt"
exclude-result-prefixes="sverb xverb lxslt d"
version='1.0'>
<!-- ********************************************************************
$Id: callout.xsl 9668 2012-11-28 00:47:59Z bobstayton $
********************************************************************
This file is part of the XSL DocBook Stylesheet distribution.
See ../README or http://docbook.sf.net/release/xsl/current/ for
copyright and other information.
******************************************************************** -->
<lxslt:component prefix="xverb"
functions="insertCallouts"/>
<xsl:template match="d:programlistingco|d:screenco">
<xsl:variable name="verbatim" select="d:programlisting|d:screen"/>
<xsl:variable name="vendor" select="system-property('xsl:vendor')"/>
<xsl:choose>
<xsl:when test="$use.extensions != '0'
and $callouts.extension != '0'">
<xsl:variable name="rtf">
<xsl:apply-templates select="$verbatim">
<xsl:with-param name="suppress-numbers" select="'1'"/>
</xsl:apply-templates>
</xsl:variable>
<xsl:variable name="rtf-with-callouts">
<xsl:choose>
<xsl:when test="contains($vendor, 'SAXON ')">
<xsl:copy-of select="sverb:insertCallouts(d:areaspec,$rtf)"/>
</xsl:when>
<xsl:when test="contains($vendor, 'Apache Software Foundation')">
<xsl:copy-of select="xverb:insertCallouts(d:areaspec,$rtf)"/>
</xsl:when>
<xsl:otherwise>
<xsl:message terminate="yes">
<xsl:text>Don't know how to do callouts with </xsl:text>
<xsl:value-of select="$vendor"/>
</xsl:message>
</xsl:otherwise>
</xsl:choose>
</xsl:variable>
<xsl:choose>
<xsl:when test="$verbatim/@linenumbering = 'numbered'
and $linenumbering.extension != '0'">
<xsl:call-template name="number.rtf.lines">
<xsl:with-param name="rtf" select="$rtf-with-callouts"/>
<xsl:with-param name="pi.context"
select="d:programlisting|d:screen"/>
</xsl:call-template>
<xsl:apply-templates select="d:calloutlist"/>
</xsl:when>
<xsl:otherwise>
<xsl:copy-of select="$rtf-with-callouts"/>
<xsl:apply-templates select="d:calloutlist"/>
</xsl:otherwise>
</xsl:choose>
</xsl:when>
<xsl:otherwise>
<xsl:apply-templates/>
</xsl:otherwise>
</xsl:choose>
</xsl:template>
<xsl:template match="d:areaspec|d:areaset|d:area">
</xsl:template>
<xsl:template match="d:areaset" mode="conumber">
<xsl:number count="d:area|d:areaset" format="1"/>
</xsl:template>
<xsl:template match="d:area" mode="conumber">
<xsl:number count="d:area|d:areaset" format="1"/>
</xsl:template>
<xsl:template match="d:co">
<xsl:param name="coref"/>
<!-- link to the callout? -->
<xsl:variable name="linkend">
<xsl:choose>
<!-- if more than one target, choose the first -->
<xsl:when test="contains(normalize-space(@linkends), ' ')">
<xsl:value-of select="substring-before(normalize-space(@linkends), ' ')"/>
</xsl:when>
<xsl:when test="string-length(normalize-space(@linkends)) != 0">
<xsl:value-of select="normalize-space(@linkends)"/>
</xsl:when>
<xsl:otherwise>
</xsl:otherwise>
</xsl:choose>
</xsl:variable>
<xsl:choose>
<xsl:when test="string-length($linkend) != 0">
<fo:basic-link internal-destination="{$linkend}">
<xsl:choose>
<xsl:when test="$coref">
<xsl:call-template name="anchor">
<xsl:with-param name="node" select="$coref"/>
<xsl:with-param name="conditional" select="0"/>
</xsl:call-template>
</xsl:when>
<xsl:otherwise>
<xsl:call-template name="anchor">
<xsl:with-param name="conditional" select="0"/>
</xsl:call-template>
</xsl:otherwise>
</xsl:choose>
<xsl:apply-templates select="." mode="callout-bug"/>
</fo:basic-link>
</xsl:when>
<xsl:otherwise>
<fo:inline>
<xsl:choose>
<xsl:when test="$coref">
<xsl:call-template name="anchor">
<xsl:with-param name="node" select="$coref"/>
<xsl:with-param name="conditional" select="0"/>
</xsl:call-template>
</xsl:when>
<xsl:otherwise>
<xsl:call-template name="anchor">
<xsl:with-param name="conditional" select="0"/>
</xsl:call-template>
</xsl:otherwise>
</xsl:choose>
<xsl:apply-templates select="." mode="callout-bug"/>
</fo:inline>
</xsl:otherwise>
</xsl:choose>
</xsl:template>
<xsl:template match="d:coref">
<!-- this relies on the fact that we can process the "co" that's -->
<!-- "over there" as if it were "right here" -->
<xsl:variable name="co" select="key('id', @linkend)"/>
<xsl:choose>
<xsl:when test="not($co)">
<xsl:message>
<xsl:text>Error: coref link is broken: </xsl:text>
<xsl:value-of select="@linkend"/>
</xsl:message>
</xsl:when>
<xsl:when test="local-name($co) != 'co'">
<xsl:message>
<xsl:text>Error: coref doesn't point to a co: </xsl:text>
<xsl:value-of select="@linkend"/>
</xsl:message>
</xsl:when>
<xsl:otherwise>
<!-- process it as if it were the co itself -->
<xsl:apply-templates select="$co">
<xsl:with-param name="coref" select="."/>
</xsl:apply-templates>
</xsl:otherwise>
</xsl:choose>
</xsl:template>
<xsl:template match="d:co" mode="callout-bug">
<xsl:call-template name="callout-bug">
<xsl:with-param name="conum">
<xsl:number count="d:co"
level="any"
from="d:programlisting|d:screen|d:literallayout|d:synopsis"
format="1"/>
</xsl:with-param>
</xsl:call-template>
</xsl:template>
<xsl:template name="callout-bug">
<xsl:param name="conum" select='1'/>
<xsl:choose>
<!-- Draw callouts as images -->
<xsl:when test="$callout.graphics != '0'
and $conum <= $callout.graphics.number.limit">
<xsl:variable name="filename"
select="concat($callout.graphics.path, $conum,
$callout.graphics.extension)"/>
<fo:external-graphic content-width="{$callout.icon.size}"
width="{$callout.icon.size}">
<xsl:attribute name="src">
<xsl:choose>
<xsl:when test="$fop.extensions != 0
or $arbortext.extensions != 0">
<xsl:value-of select="$filename"/>
</xsl:when>
<xsl:otherwise>
<xsl:text>url(</xsl:text>
<xsl:value-of select="$filename"/>
<xsl:text>)</xsl:text>
</xsl:otherwise>
</xsl:choose>
</xsl:attribute>
</fo:external-graphic>
</xsl:when>
<xsl:when test="$callout.unicode != 0
and $conum <= $callout.unicode.number.limit">
<xsl:variable name="comarkup">
<xsl:choose>
<xsl:when test="$callout.unicode.start.character = 10102">
<xsl:choose>
<xsl:when test="$conum = 1">❶</xsl:when>
<xsl:when test="$conum = 2">❷</xsl:when>
<xsl:when test="$conum = 3">❸</xsl:when>
<xsl:when test="$conum = 4">❹</xsl:when>
<xsl:when test="$conum = 5">❺</xsl:when>
<xsl:when test="$conum = 6">❻</xsl:when>
<xsl:when test="$conum = 7">❼</xsl:when>
<xsl:when test="$conum = 8">❽</xsl:when>
<xsl:when test="$conum = 9">❾</xsl:when>
<xsl:when test="$conum = 10">❿</xsl:when>
<xsl:when test="$conum = 11">⓫</xsl:when>
<xsl:when test="$conum = 12">⓬</xsl:when>
<xsl:when test="$conum = 13">⓭</xsl:when>
<xsl:when test="$conum = 14">⓮</xsl:when>
<xsl:when test="$conum = 15">⓯</xsl:when>
<xsl:when test="$conum = 16">⓰</xsl:when>
<xsl:when test="$conum = 17">⓱</xsl:when>
<xsl:when test="$conum = 18">⓲</xsl:when>
<xsl:when test="$conum = 19">⓳</xsl:when>
<xsl:when test="$conum = 20">⓴</xsl:when>
</xsl:choose>
</xsl:when>
<xsl:when test="$callout.unicode.start.character = 9312">
<xsl:choose>
<xsl:when test="$conum = 1">①</xsl:when>
<xsl:when test="$conum = 2">②</xsl:when>
<xsl:when test="$conum = 3">③</xsl:when>
<xsl:when test="$conum = 4">④</xsl:when>
<xsl:when test="$conum = 5">⑤</xsl:when>
<xsl:when test="$conum = 6">⑥</xsl:when>
<xsl:when test="$conum = 7">⑦</xsl:when>
<xsl:when test="$conum = 8">⑧</xsl:when>
<xsl:when test="$conum = 9">⑨</xsl:when>
<xsl:when test="$conum = 10">⑩</xsl:when>
<xsl:when test="$conum = 11">⑪</xsl:when>
<xsl:when test="$conum = 12">⑫</xsl:when>
<xsl:when test="$conum = 13">⑬</xsl:when>
<xsl:when test="$conum = 14">⑭</xsl:when>
<xsl:when test="$conum = 15">⑮</xsl:when>
<xsl:when test="$conum = 16">⑯</xsl:when>
<xsl:when test="$conum = 17">⑰</xsl:when>
<xsl:when test="$conum = 18">⑱</xsl:when>
<xsl:when test="$conum = 19">⑲</xsl:when>
<xsl:when test="$conum = 20">⑳</xsl:when>
</xsl:choose>
</xsl:when>
<xsl:otherwise>
<xsl:message>
<xsl:text>Don't know how to generate Unicode callouts </xsl:text>
<xsl:text>when $callout.unicode.start.character is </xsl:text>
<xsl:value-of select="$callout.unicode.start.character"/>
</xsl:message>
<fo:inline background-color="#404040"
color="white"
padding-top="0.1em"
padding-bottom="0.1em"
padding-start="0.2em"
padding-end="0.2em"
baseline-shift="0.1em"
font-family="{$body.fontset}"
font-weight="bold"
font-size="75%">
<xsl:value-of select="$conum"/>
</fo:inline>
</xsl:otherwise>
</xsl:choose>
</xsl:variable>
<xsl:choose>
<xsl:when test="$callout.unicode.font != ''">
<fo:inline font-family="{$callout.unicode.font}">
<xsl:copy-of select="$comarkup"/>
</fo:inline>
</xsl:when>
<xsl:otherwise>
<xsl:copy-of select="$comarkup"/>
</xsl:otherwise>
</xsl:choose>
</xsl:when>
<!-- Most safe: draw a dark gray square with a white number inside -->
<xsl:otherwise>
<fo:inline background-color="#404040"
color="white"
padding-top="0.1em"
padding-bottom="0.1em"
padding-start="0.2em"
padding-end="0.2em"
baseline-shift="0.1em"
font-family="{$body.fontset}"
font-weight="bold"
font-size="75%">
<xsl:value-of select="$conum"/>
</fo:inline>
</xsl:otherwise>
</xsl:choose>
</xsl:template>
</xsl:stylesheet>
| # | Change | User | Description | Committed | |
|---|---|---|---|---|---|
| #1 | 13895 | Paul Allen | Copying using p4convert-docbook | ||
| //guest/perforce_software/doc_build/main/docbook-xsl-ns-1.78.1/fo/callout.xsl | |||||
| #1 | 12728 | eedwards |
Upgrade ANT doc build infrastructure to assemble PDFs: - remove non-namespaced DocBook source and add namespaced DocBook source. - add Apache FOP 1.1 - copy fonts, images, XSL into _build, establishing new asset structure. The original structure remains until all guides using it can be upgraded, and several other issues can be resolved. - updated build.xml to allow for per-target build properties. - upgraded the P4SAG to use the new infrastructure. - tweaked admonition presentation in PDFs to remove admonition graphics, and resemble closely the presentation used in the new HTML layout, including the same colors. With these changes, building PDFs involves using a shell, navigating into the guide's directory (just P4SAG for now), and executing "ant pdf". Issues still to be resolved: - PDF generation encounters several warnings about missing fonts (bold versions of Symbol and ZapfDingbats), and a couple of locations where the page content exceeds the defined content area. - Due to issues within Apache FOP, PDF generation emits a substantial amount of output that is not easily suppressed without losing important warning information. - Apache FOP's interface to ANT does not expose a way to set the font base directory. The current configuration does work under Mac OSX, but further testing on Windows will need to be done to determine if the relative paths defined continue to work. The workaround is for Windows users to customize the fop-config.xml to provide absolute system paths to the required fonts. - HTML generation needs further browser testing, and exhibits broken navigation on iOS browsers within the TOC sidebar. - A number of PDF and HTML presentation tweaks still need to be made, for example: sidebars, gui* DocBook tags, whitespace, section separation, etc. |
||