95svn2p4.t #2

#!/usr/local/bin/perl -w

=head1 NAME

svn.t - testing of vcp svn i/o

=cut

use strict ;

use Carp ;
use Cwd ;
use File::Spec ;
use Test ;

use VCP::TestUtils ;

my @vcp = vcp_cmd ;

my $t = -d 't' ? 't/' : '' ;

my $cwd = cwd;

if ( $^O =~ /Win32/ ) {
    $cwd =~ s{\A[A-Z]:}{};
}

my $module = 'foo' ;  ## Must match the rev_root in the testrevml files

my @revml_out_spec = ( "sort:", "--", "revml:" ) ;

my $p4d_borken = $ENV{P4DBORKEN} || p4d_borken ;

sub check {
   croak "test failed and FATALTEST set" if ! $_[0];
}


my $infile_0  = "${t}test-svn-in-0.revml";
my $infile_1  = "${t}test-svn-in-1.revml";
my $svnroot_0 = "${t}svnroot_0";
my $svnroot_1 = "${t}svnroot_1";

my $svn_spec_0        = "svn:file://$cwd/$svnroot_0:/$module" ;
my $svn_spec_1        = "svn:file://$cwd/$svnroot_1:/$module" ;

## Where to put the destination repository
my $p4root = tmpdir "p4root";

my $state_location = tmpdir "vcp_state";

my $p4_spec = "p4:p4_t_user\@$p4root:";

my $repo_id;

my @tests = (
##
## svn to p4
##
sub {
   return skip $p4d_borken, 1 if $p4d_borken ;

   my $svn_spec = $svn_spec_0;

   ## TODO: test rewriting label branches to be labels; this will need
   ## gentrevml to write label branches.
   eval { run [ @vcp, "vcp:-" ], \<<TOHERE; };
Source:      $svn_spec_0/... --repo-id=svn:test_repository

Destination: $p4_spec//depot/...
                --init-p4d
                --db-dir=$state_location
                --repo-id=p4:test_repository

Map:
        tags/(*)/... <<label_parent(\$1)>>

TOHERE
   ok $@ || '', '';  # next sub checks this better
},

##
## check previous test by reading resulting p4 into revml,
## and comparing to the p4 version of the generated source revml.
##
sub {
   return skip $p4d_borken, 1 if $p4d_borken ;

   my $out;
   eval {
      run [ @vcp,
         "$p4_spec//depot/...",
         "--repo-id=p4:test_repository",
         "--run-p4d",
         @revml_out_spec,
         "--db-dir=$state_location",
         "--repo-id=revml:test_repository",
      ], \undef, \$out;
   };
   die $@ if $@;

   my $infile  = $t . "test-p4-in-0.revml";
   my $in = slurp $infile ;

   s_content  qw( rep_desc time user_id rep_type     ), \$in, \$out ;
   s_content  qw( rev_root                           ), \$in, "depot" ;
   rm_elts    qw( p4_info change_id source_change_id ), \$in, \$out ;

   $out =~ s{[\r\n]*\[vcp\] .*?(\r?\n)}{$1}g;
       ## Clean up the "[vcp] using estimated..." addition to comments
   
   $in =~ s{(id="|id>)/ignored}{$1//depot}g;

   $in =~ s{^\s*<label>\w+(081|085|089|093|101)</label>[ \t]*\r?\n}{}mg;
       ## These labels are applied in batch 2 when building the svn repo.

   ok_or_diff $out, $in;
},

##
## Incremental svn->p4->revml update (svn to p4 part)
##
sub {
   return skip $p4d_borken, 1 if $p4d_borken ;

   eval { run [ @vcp, "vcp:-" ], \<<TOHERE; };
Source:      $svn_spec_1/...
                --repo-id=svn:test_repository
                --continue

Destination: $p4_spec//depot/... 
                --run-p4d
                --db-dir=$state_location
                --repo-id=p4:test_repository

Map:
        tags/(*)/... <<label_parent(\$1)>>

TOHERE
   ok $@ || '', '';  # next sub checks this better
},

##
## part 2 of Incremental svn->p4->revml update (p4 to revml, check result)
##
sub {
   return skip $p4d_borken, 1 if $p4d_borken ;
   return skip 'last test did not complete', 1 if $@;
   
   my $out ;
   
   eval {
      run [ @vcp,
         "$p4_spec//depot/...",
            "--repo-id=p4:test_repository",
            "--continue",
            "--run-p4d",
         @revml_out_spec,
            "--db-dir=$state_location",
            "--repo-id=revml:test_repository",
      ], \undef, \$out;
   };
   die $@ if $@;
   
   my $infile  = $t . "test-p4-in-1.revml";
   my $in = slurp $infile ;
   
   s_content  qw( rep_desc time user_id rep_type     ), \$in, \$out ;
   s_content  qw( rev_root                           ), \$in, "depot" ;
   rm_elts    qw( p4_info change_id source_change_id ), \$in, \$out ;
       ## svn has no change_id and the p4 input file and output file have
       ## different ones because the svn->p4 splits a change in to two
       ## to put the branch operation in its own change.
   
   $out =~ s{[\r\n]*\[vcp\] .*?(\r?\n)}{$1}g;
       ## Clean up the "[vcp] using estimated..." addition to comments
   
   $in =~ s{(id="|id>)/ignored}{$1//depot}g;

   $in =~ s{^\s*<label>\w+(157|161|165|168|169|181)</label>[ \t]*\r?\n}{}mg;
       ## These labels are never applied (they would be applied
       ## after the final change in the second batch generated by gentrevml.

   ok_or_diff $out, $in;
},

##
## svn->p4->revml, re-rooting a dir tree
##
## Do this after the above tests so that we can start with an empty repo.
##
sub {
   return skip $p4d_borken, 1 if $p4d_borken ;

   ## Start anew
   rm_dir_tree $p4root;
   rm_dir_tree $state_location;

   eval {
      run [ @vcp,
         "$svn_spec_0/main/a/deeply/...",
         "$p4_spec//depot/new/...",
            "--db-dir=$state_location",
            "--repo-id=p4:test_repository",
            "--init-p4d",
      ],
         \undef;
   };
   ok $@ || '', '';  # next sub checks this better
},

sub {   
   return skip $p4d_borken, 1 if $p4d_borken ;
   my $out ;

   eval {
      run [ @vcp,
         "$p4_spec//depot/new/...",
            "--repo-id=p4:test_repository",
            "--run-p4d",
         @revml_out_spec,
            "--db-dir=$state_location",
            "--repo-id=revml:test_repository",
      ], \undef, \$out;
   };
   die $@ if $@;

   my $infile  = $t . "test-p4-in-0.revml";
   my $in = slurp $infile ;

   s_content  qw( rep_desc time user_id rep_type  ), \$in, \$out ;
   s_content  qw( rev_root                        ), \$in, "depot/new" ;
   rm_elts    qw( p4_info                         ), \$in, \$out ;

   ## Strip out all files from $in that shouldn't be there
   rm_elts    qw( rev ), qr{(?:(?!a/deeply).)*?}s, \$in ;

   ## Adjust the $in paths to look like the result paths.  $in is
   ## now the "expected" output.
   $in =~ s{<(name|source_name)>main/a/deeply/}{<$1>}g ;

   $in =~ s{(id="|id>)/ignored/main/a/deeply}{$1//depot/new}g;  #"# cperl syntax highlight fix

   $in =~ s{^\s*<label>\w+</label>[ \t]*\r?\n}{}mg;
       ## The above svn->p4 command does not capture labels.

   ok_or_diff $out, $in;
},

) ;

plan tests => scalar( @tests ) ;

my $why_skip ;
$why_skip .= p4_borken;
$why_skip .= svn_borken;
$why_skip ? skip( $why_skip, 0 ) : $_->() for @tests ;