90revml2p4_0.t #1

#!/usr/local/bin/perl -w

=head1 NAME

p4.t - testing of vcp p4 i/o

=cut

use strict ;

use Carp ;
use File::Path ;
use File::Spec ;
use POSIX ':sys_wait_h' ;
use Test ;
use VCP::TestUtils ;

# use eq_or_diff from Test::Differences if available,
# else just use ok.
eval "use Test::Differences";
sub ok_or_diff {
   goto &eq_or_diff if defined &eq_or_diff;
   goto &Test::ok;
}


my @vcp = vcp_cmd ;

my $t = -d 't' ? 't/' : '' ;

my $p4_options ;
my $p4_spec_base ;
my $p4_rev_root ;
my $p4_spec ;



my @tests = (

###
# create empty p4 repository
sub {
   $ENV{P4USER}   = "foobar_user" ;
   $ENV{P4PORT}   = "foobar_port" ;
   $ENV{P4CLIENT} = "foobar_client" ;
   $ENV{P4PASSWD} = "foobar_passwd" ;

   $p4_options = launch_p4d "p4_", { 
      repo_dir    => "${t}p4root_0",
      rm_repo_dir => 1,                                    
   } ;
   $p4_spec_base = "p4:$p4_options->{user}:\@$p4_options->{port}:" ;
   $p4_rev_root = "//depot/foo/" ;
   $p4_spec = "$p4_spec_base$p4_rev_root" ;
   ok 1 ;
},

##
## Empty import
##
sub {
   run [ @vcp, "revml:-", $p4_spec ], \"<revml/>" ; #"# de-confuse emacs cperl-mode
   ok $?, 0, "`vcp revml:- $p4_spec` return value"  ;
},

## revml -> p4 bootstrap export
sub {
   my $infile  = $t . "test-p4-in-0.revml" ;
   ok run [ @vcp, "revml:$infile", $p4_spec ], \undef;
},

## slurp $infile and analyze with regexps to count
## number of unique named files and the highest change
## number for each file,  then use the p4 files command line
## client to see if the repository really contains all that.

## detailed analysis of this import is left to 91p42revml.t             

sub {
   my $infile  = $t . "test-p4-in-0.revml" ;

   #print map "$_ => $p4_options->{$_}, ", keys %$p4_options;
   #print "\n";

   my $revs1 = parse_files_and_revids_from_revml $infile ;

   my $output;
   run_p4 [ "files", "//..." ], \undef, \$output, $p4_options;
   my $h = {};
   while ( $output =~ m{(.*)#(\d+) - }g ) {
      die "'p4 files' output lines weren't preceeded by $p4_rev_root as expected"
         if index( $1, $p4_rev_root ) < 0 ;
      my $name = substr $1, length $p4_rev_root ;

      die "duplicate file names in p4 files output"
         if exists $h->{$name};
      $h->{$name} = $2 ;
   }

   my $revs2 = join "", map { "$_ => $h->{$_}\n" } sort keys %$h;

   ok_or_diff $revs1, $revs2;
},



) ;



plan tests => scalar @tests ;

my $p4d_borken = p4d_borken ;

my $why_skip ;
$why_skip .= "p4 command not found\n"  unless ( `p4 -V`  || 0 ) =~ /^Perforce/ ;
$why_skip .= "$p4d_borken\n"           if $p4d_borken ;

$why_skip ? skip( $why_skip, '' ) : $_->() for @tests ;