download_p4api.cmd #2

::  Script to download required P4API's from the perforce website, 
::  and extract them into the correct locations for the following builds:
::  * Visual Studio
::  * NTX86
::  * NTX64

@echo off

pushd "%~dp0"

if not exist "lib.ntx86"  mkdir "lib.ntx86"
if not exist "lib.vs2005" mkdir "lib.vs2005"
if not exist "lib.ntx64"  mkdir "lib.ntx64"

set FTPFILE="%CD%\ftp.script"

rem build the ftp script file

echo bin>%FTPFILE%
echo cd /perforce/r07.3/bin.ntx86/>>%FTPFILE%
echo lcd lib.ntx86>>%FTPFILE%
echo get p4api_vs2005_static.zip>>%FTPFILE%
echo lcd ..\lib.vs2005>>%FTPFILE%
echo get p4api_vs2005_static_vsdebug.zip>>%FTPFILE%
echo cd /perforce/r07.3/bin.ntx64/>>%FTPFILE%
echo lcd ..\lib.ntx64>>%FTPFILE%
echo get p4api_vs2005_static.zip>>%FTPFILE%
echo quit>>%FTPFILE%

ftp -A -s:%FTPFILE% ftp.perforce.com

del /q /f %FTPFILE%

call :extractapi lib.ntx86
call :extractapi lib.vs2005
call :extractapi lib.ntx64

popd

goto :eof

:extractapi
    pushd "%~1"
    if exist p4api rd /s /q p4api
    ..\tools\unixutils\unzip *.zip
    move p4api-* p4api
    popd
goto :eof